File Manager

003 File Manager

Current Path: /usr/src/contrib/llvm-project/lldb/source/Commands

usr / src / contrib / llvm-project / lldb / source / Commands /

📁 ..
📄 CommandCompletions.cpp(21.8 KB)
📄 CommandObjectApropos.cpp(3.61 KB)
📄 CommandObjectApropos.h(904 B)
📄 CommandObjectBreakpoint.cpp(81.05 KB)
📄 CommandObjectBreakpoint.h(1.72 KB)
📄 CommandObjectBreakpointCommand.cpp(25.81 KB)
📄 CommandObjectBreakpointCommand.h(902 B)
📄 CommandObjectCommands.cpp(63.2 KB)
📄 CommandObjectCommands.h(877 B)
📄 CommandObjectDisassemble.cpp(17.74 KB)
📄 CommandObjectDisassemble.h(3.05 KB)
📄 CommandObjectExpression.cpp(23.86 KB)
📄 CommandObjectExpression.h(3.63 KB)
📄 CommandObjectFrame.cpp(42.35 KB)
📄 CommandObjectFrame.h(852 B)
📄 CommandObjectGUI.cpp(1.79 KB)
📄 CommandObjectGUI.h(870 B)
📄 CommandObjectHelp.cpp(8.53 KB)
📄 CommandObjectHelp.h(2.35 KB)
📄 CommandObjectLanguage.cpp(933 B)
📄 CommandObjectLanguage.h(883 B)
📄 CommandObjectLog.cpp(17.02 KB)
📄 CommandObjectLog.h(1004 B)
📄 CommandObjectMemory.cpp(61.7 KB)
📄 CommandObjectMemory.h(799 B)
📄 CommandObjectMultiword.cpp(13.54 KB)
📄 CommandObjectPlatform.cpp(61.17 KB)
📄 CommandObjectPlatform.h(997 B)
📄 CommandObjectPlugin.cpp(2.68 KB)
📄 CommandObjectPlugin.h(799 B)
📄 CommandObjectProcess.cpp(55.63 KB)
📄 CommandObjectProcess.h(866 B)
📄 CommandObjectQuit.cpp(3.81 KB)
📄 CommandObjectQuit.h(930 B)
📄 CommandObjectRegister.cpp(15.66 KB)
📄 CommandObjectRegister.h(1.04 KB)
📄 CommandObjectReproducer.cpp(17.86 KB)
📄 CommandObjectReproducer.h(851 B)
📄 CommandObjectSettings.cpp(38.87 KB)
📄 CommandObjectSettings.h(873 B)
📄 CommandObjectSource.cpp(47.71 KB)
📄 CommandObjectSource.h(863 B)
📄 CommandObjectStats.cpp(3.52 KB)
📄 CommandObjectStats.h(791 B)
📄 CommandObjectTarget.cpp(177.86 KB)
📄 CommandObjectTarget.h(859 B)
📄 CommandObjectThread.cpp(78.3 KB)
📄 CommandObjectThread.h(826 B)
📄 CommandObjectType.cpp(98.61 KB)
📄 CommandObjectType.h(774 B)
📄 CommandObjectVersion.cpp(1.18 KB)
📄 CommandObjectVersion.h(898 B)
📄 CommandObjectWatchpoint.cpp(40.55 KB)
📄 CommandObjectWatchpoint.h(1.04 KB)
📄 CommandObjectWatchpointCommand.cpp(23.68 KB)
📄 CommandObjectWatchpointCommand.h(902 B)
📄 Options.td(58.93 KB)
📄 OptionsBase.td(7.3 KB)

Editing: OptionsBase.td

// The fields below describe how the fields of `OptionDefinition` struct are
// initialized by different definitions in the Options.td and this file.
////////////////////////////////////////////////////////////////////////////////
// Field: usage_mask
// Default value: LLDB_OPT_SET_ALL (Option allowed in all groups)
// Set by:
//  - `Group`: Sets a single group to this option.
//             Example: def foo : Option<"foo", "f">, Group<1>;
//  - `Groups`: Sets a given list of group numbers.
//              Example: def foo : Option<"foo", "f">, Groups<[1,4,6]>;
//  - `GroupRange`: Sets an interval of groups. Start and end are inclusive.
//                  Example: def foo : Option<"foo", "f">, GroupRange<1, 4>;
//                           Sets group 1, 2, 3, 4 for the option.
////////////////////////////////////////////////////////////////////////////////
// Field: required
// Default value: false (Not required)
// Set by:
//   - `Required`: Marks the option as required.
//              Example: def foo : Option<"foo", "f">, Required;
////////////////////////////////////////////////////////////////////////////////
// Field: long_option
// Default value: not available (has to be defined in Option)
// Set by:
//   - `Option` constructor: Already set by constructor.
//                           Example: def foo : Option<"long-option", "l">
//                                                           ^
//                                                    long option value
////////////////////////////////////////////////////////////////////////////////
// Field: short_option
// Default value: not available (has to be defined in Option)
// Set by:
//   - `Option` constructor: Already set by constructor.
//                           Example: def foo : Option<"long-option", "l">
//                                                                     ^
//                                                                short option
////////////////////////////////////////////////////////////////////////////////
// Field: option_has_arg
// Default value: OptionParser::eNoArgument (No argument allowed)
// Set by:
//  - `OptionalArg`: Sets the argument type and marks it as optional.
//  - `Arg`: Sets the argument type and marks it as required.
//  - `EnumArg`: Sets the argument type to an enum and marks it as required.
//  - `OptionalEnumArg`: Same as EnumArg but marks it as optional.
// See argument_type field for more info.
////////////////////////////////////////////////////////////////////////////////
// Field: validator
// Default value: 0 (No validator for option)
// Set by:
//  - `Validator`: Sets the value to a given validator (which has to exist in
//                 the surrounding code.
////////////////////////////////////////////////////////////////////////////////
// Field: enum_values
// Default value: {} (No enum associated with this option)
// Set by:
//  - `OptionalEnumArg`:
//  - `EnumArg`: Sets the argument type and assigns it a enum holding the valid
//               values. The enum needs to be a variable in the including code.
//               Marks the option as required (see option_has_arg).
//               Example: def foo : Option<"foo", "f">,
//                          EnumArg<"SortOrder",
//                          "OptionEnumValues(g_sort_option_enumeration)">;
////////////////////////////////////////////////////////////////////////////////
// Field: completion_type
// Default value: CommandCompletions::eNoCompletion (no tab completion)
// Set by:
//  - `Completion`: Gives the option a single completion kind.
//                  Example: def foo : Option<"foo", "f">,
//                             Completion<"DiskFile">;
//                           Sets the completion to eDiskFileCompletion
//
//  - `Completions`: Sets a given kinds of completions.
//                   Example: def foo : Option<"foo", "f">,
//                              Completions<["DiskFile", "DiskDirectory"]>;
//                            Sets the completion to
//                            `eDiskFileCompletion | eDiskDirectoryCompletion`.
////////////////////////////////////////////////////////////////////////////////
// Field: argument_type
// Default value: eArgTypeNone
// Set by:
//  - `OptionalArg`: Sets the argument type and marks it as optional.
//                   Example: def foo : Option<"foo", "f">, OptionalArg<"Pid">;
//                   Sets the argument type to eArgTypePid and marks option as
//                   optional (see option_has_arg).
//  - `Arg`: Sets the argument type and marks it as required.
//           Example: def foo : Option<"foo", "f">, Arg<"Pid">;
//                    Sets the argument type to eArgTypePid and marks option as
//                    required (see option_has_arg).
//  - `OptionalEnumArg`:
//  - `EnumArg`: Sets the argument type and assigns it a enum holding the valid
//               values. The enum needs to be a variable in the including code.
//               Marks the option as required (see option_has_arg).
//               Example: def foo : Option<"foo", "f">,
//                          EnumArg<"SortOrder",
//                          "OptionEnumValues(g_sort_option_enumeration)">;
//               Use `OptionalEnumArg` for having an option enum argument.
////////////////////////////////////////////////////////////////////////////////
// Field: usage_text
// Default value: ""
// Set by:
//  - `Desc`: Sets the description for the given option.
//            Example: def foo : Option<"foo", "f">, Desc<"does nothing.">;
//                     Sets the description to "does nothing.".

// Base class for all options.
class Option<string fullname, string shortname> {
  string FullName = fullname;
  string ShortName = shortname;
  // The full associated command/subcommand such as "settings set".
  string Command;
}

// Moves the option into a list of option groups.
class Groups<list<int> groups> {
  list<int> Groups = groups;
}

// Moves the option in all option groups in a range.
// Start and end values are inclusive.
class GroupRange<int start, int end> {
  int GroupStart = start;
  int GroupEnd = end;
}
// Moves the option in a single option group.
class Group<int group> {
  int GroupStart = group;
  int GroupEnd = group;
}

// Sets the description for the option that should be
// displayed to the user.
class Desc<string description> {
  string Description = description;
}

// Marks the option as required when calling the
// associated command.
class Required {
  bit Required = 1;
}

// Gives the option an optional argument.
class OptionalArg<string type> {
  string ArgType = type;
  bit OptionalArg = 1;
}

// Gives the option an required argument.
class Arg<string type> {
  string ArgType = type;
}

// Gives the option an required argument.
class EnumArg<string type, string enum> {
  string ArgType = type;
  string ArgEnum = enum;
}

// Gives the option an required argument.
class OptionalEnumArg<string type, string enum> {
  string ArgType = type;
  string ArgEnum = enum;
  bit OptionalArg = 1;
}

// Sets the available completions for the given option.
class Completions<list<string> completions> {
  list<string> Completions = completions;
}
// Sets a single completion for the given option.
class Completion<string completion> {
  list<string> Completions = [completion];
}

// Sets the validator for a given option.
class Validator<string validator> {
  string Validator = validator;
}

003 File Manager

Editing: OptionsBase.td

Upload File

Create Folder