File Manager

003 File Manager

Current Path: /usr/src/contrib/llvm-project/compiler-rt/lib/builtins/hexagon

usr / src / contrib / llvm-project / compiler-rt / lib / builtins / hexagon /

📁 ..
📄 common_entry_exit_abi1.S(2.47 KB)
📄 common_entry_exit_abi2.S(6.9 KB)
📄 common_entry_exit_legacy.S(4.31 KB)
📄 dfaddsub.S(8.1 KB)
📄 dfdiv.S(9.62 KB)
📄 dffma.S(13.39 KB)
📄 dfminmax.S(1.74 KB)
📄 dfmul.S(9.31 KB)
📄 dfsqrt.S(8.4 KB)
📄 divdi3.S(2.4 KB)
📄 divsi3.S(1.36 KB)
📄 fastmath2_dlib_asm.S(12.11 KB)
📄 fastmath2_ldlib_asm.S(8.57 KB)
📄 fastmath_dlib_asm.S(10.52 KB)
📄 memcpy_forward_vp4cp4n2.S(3.42 KB)
📄 memcpy_likely_aligned.S(1.31 KB)
📄 moddi3.S(2.36 KB)
📄 modsi3.S(1.09 KB)
📄 sfdiv_opt.S(1.44 KB)
📄 sfsqrt_opt.S(1.77 KB)
📄 udivdi3.S(2.23 KB)
📄 udivmoddi4.S(2.24 KB)
📄 udivmodsi4.S(1.14 KB)
📄 udivsi3.S(1.06 KB)
📄 umoddi3.S(2.26 KB)
📄 umodsi3.S(1013 B)

Editing: divsi3.S

//===----------------------Hexagon builtin routine ------------------------===//
//
// Part of the LLVM Project, under the Apache License v2.0 with LLVM Exceptions.
// See https://llvm.org/LICENSE.txt for license information.
// SPDX-License-Identifier: Apache-2.0 WITH LLVM-exception
//
//===----------------------------------------------------------------------===//

.macro FUNCTION_BEGIN name
	.text
        .p2align 5
	.globl \name
	.type  \name, @function
\name:
	.endm

.macro FUNCTION_END name
	.size  \name, . - \name
	.endm

FUNCTION_BEGIN __hexagon_divsi3
	{
		p0 = cmp.ge(r0,#0)
		p1 = cmp.ge(r1,#0)
		r1 = abs(r0)
		r2 = abs(r1)
	}
	{
		r3 = cl0(r1)
		r4 = cl0(r2)
		r5 = sub(r1,r2)
		p2 = cmp.gtu(r2,r1)
	}
#if (__HEXAGON_ARCH__ == 60)
	{
		r0 = #0
		p1 = xor(p0,p1)
		p0 = cmp.gtu(r2,r5)
	}
		if (p2) jumpr r31
#else
	{
		r0 = #0
		p1 = xor(p0,p1)
		p0 = cmp.gtu(r2,r5)
		if (p2) jumpr r31
	}
#endif
	{
		r0 = mux(p1,#-1,#1)
		if (p0) jumpr r31
		r4 = sub(r4,r3)
		r3 = #1
	}
	{
		r0 = #0
		r3:2 = vlslw(r3:2,r4)
		loop0(1f,r4)
	}
	.falign
1:
	{
		p0 = cmp.gtu(r2,r1)
		if (!p0.new) r1 = sub(r1,r2)
		if (!p0.new) r0 = add(r0,r3)
		r3:2 = vlsrw(r3:2,#1)
	}:endloop0
	{
		p0 = cmp.gtu(r2,r1)
		if (!p0.new) r0 = add(r0,r3)
		if (!p1) jumpr r31
	}
	{
		r0 = neg(r0)
		jumpr r31
	}
FUNCTION_END __hexagon_divsi3

.globl __qdsp_divsi3
  .set   __qdsp_divsi3, __hexagon_divsi3

003 File Manager

Editing: divsi3.S

Upload File

Create Folder