File Manager

003 File Manager

Current Path: /usr/src/sys/contrib/openzfs/config

usr / src / sys / contrib / openzfs / config /

📁 ..
📄 .gitignore(96 B)
📄 Abigail.am(873 B)
📄 Rules.am(1.77 KB)
📄 Substfiles.am(1.11 KB)
📄 always-arch.m4(855 B)
📄 always-compiler-options.m4(5.25 KB)
📄 always-python.m4(2.18 KB)
📄 always-pyzfs.m4(2.84 KB)
📄 always-sed.m4(539 B)
📄 always-system.m4(639 B)
📄 ax_code_coverage.m4(11.69 KB)
📄 ax_python_devel.m4(11.49 KB)
📄 ax_restore_flags.m4(881 B)
📄 ax_save_flags.m4(871 B)
📄 config.awk(334 B)
📄 config.rpath(18.14 KB)
📄 deb.am(2.98 KB)
📄 find_system_library.m4(2.93 KB)
📄 gettext.m4(14.14 KB)
📄 host-cpu-c-abi.m4(20.99 KB)
📄 iconv.m4(9.47 KB)
📄 intlmacosx.m4(3.24 KB)
📄 kernel-access-ok-type.m4(747 B)
📄 kernel-acl.m4(7.63 KB)
📄 kernel-aio-fsync.m4(534 B)
📄 kernel-automount.m4(817 B)
📄 kernel-bdi.m4(2.12 KB)
📄 kernel-bio.m4(9.91 KB)
📄 kernel-blk-queue.m4(8.08 KB)
📄 kernel-blkdev.m4(8.09 KB)
📄 kernel-block-device-operations.m4(1.76 KB)
📄 kernel-clear-inode.m4(1.4 KB)
📄 kernel-commit-metadata.m4(810 B)
📄 kernel-config-defined.m4(5.3 KB)
📄 kernel-current-time.m4(590 B)
📄 kernel-declare-event-class.m4(1.35 KB)
📄 kernel-dentry-operations.m4(4.66 KB)
📄 kernel-dirty-inode.m4(817 B)
📄 kernel-discard-granularity.m4(568 B)
📄 kernel-encode-fh-inode.m4(934 B)
📄 kernel-evict-inode.m4(701 B)
📄 kernel-fallocate.m4(697 B)
📄 kernel-file-dentry.m4(653 B)
📄 kernel-file-inode.m4(533 B)
📄 kernel-fmode-t.m4(440 B)
📄 kernel-follow-down-one.m4(576 B)
📄 kernel-fpu.m4(3.33 KB)
📄 kernel-fst-mount.m4(951 B)
📄 kernel-fsync.m4(1.18 KB)
📄 kernel-generic_io_acct.m4(2.42 KB)
📄 kernel-generic_readlink.m4(637 B)
📄 kernel-get-disk-and-module.m4(0 B)
📄 kernel-get-disk-ro.m4(455 B)
📄 kernel-get-link.m4(2.95 KB)
📄 kernel-global_page_state.m4(3.71 KB)
📄 kernel-group-info.m4(557 B)
📄 kernel-hotplug.m4(720 B)
📄 kernel-in-compat-syscall.m4(635 B)
📄 kernel-inode-create.m4(613 B)
📄 kernel-inode-getattr.m4(1.29 KB)
📄 kernel-inode-lock.m4(650 B)
📄 kernel-inode-lookup.m4(620 B)
📄 kernel-inode-set-flags.m4(542 B)
📄 kernel-inode-set-iversion.m4(560 B)
📄 kernel-inode-times.m4(1.1 KB)
📄 kernel-insert-inode-locked.m4(541 B)
📄 kernel-is_owner_or_cap.m4(639 B)
📄 kernel-kmap-atomic-args.m4(532 B)
📄 kernel-kmem-cache.m4(1.12 KB)
📄 kernel-kmem.m4(3.03 KB)
📄 kernel-kstrtoul.m4(479 B)
📄 kernel-ktime.m4(1.36 KB)
📄 kernel-kuid-helpers.m4(611 B)
📄 kernel-kuidgid.m4(543 B)
📄 kernel-lseek-execute.m4(744 B)
📄 kernel-make-request-fn.m4(4.33 KB)
📄 kernel-misc-minor.m4(885 B)
📄 kernel-mkdir-umode-t.m4(1 KB)
📄 kernel-mod-param.m4(789 B)
📄 kernel-objtool.m4(1.61 KB)
📄 kernel-pde-data.m4(422 B)
📄 kernel-percpu.m4(1.51 KB)
📄 kernel-proc-operations.m4(1.31 KB)
📄 kernel-put-link.m4(1.54 KB)
📄 kernel-rename.m4(787 B)
📄 kernel-revalidate-disk-size.m4(1.14 KB)
📄 kernel-rw.m4(1.53 KB)
📄 kernel-rwsem.m4(1.47 KB)
📄 kernel-sched.m4(2.01 KB)
📄 kernel-security-inode-init.m4(1.19 KB)
📄 kernel-set-nlink.m4(450 B)
📄 kernel-setattr-prepare.m4(748 B)
📄 kernel-sget-args.m4(609 B)
📄 kernel-show-options.m4(596 B)
📄 kernel-shrink.m4(3.96 KB)
📄 kernel-super-userns.m4(633 B)
📄 kernel-timer.m4(1.95 KB)
📄 kernel-tmpfile.m4(636 B)
📄 kernel-totalhigh_pages.m4(500 B)
📄 kernel-totalram-pages-func.m4(620 B)
📄 kernel-truncate-setsize.m4(518 B)
📄 kernel-userns-capabilities.m4(2.59 KB)
📄 kernel-usleep_range.m4(608 B)
📄 kernel-vfs-direct_IO.m4(2.7 KB)
📄 kernel-vfs-fsync.m4(464 B)
📄 kernel-vfs-getattr.m4(2.02 KB)
📄 kernel-vfs-iov_iter.m4(4.97 KB)
📄 kernel-vfs-iterate.m4(2.23 KB)
📄 kernel-vfs-rw-iterate.m4(1.93 KB)
📄 kernel-wait.m4(2.82 KB)
📄 kernel-xattr-handler.m4(11.09 KB)
📄 kernel-zlib.m4(931 B)
📄 kernel.m4(23.74 KB)
📄 lib-ld.m4(5.24 KB)
📄 lib-link.m4(31.99 KB)
📄 lib-prefix.m4(9.43 KB)
📄 mount-helper.m4(240 B)
📄 nls.m4(1.2 KB)
📄 pkg.m4(10.01 KB)
📄 po.m4(18.39 KB)
📄 progtest.m4(3.02 KB)
📄 rpm.am(3.72 KB)
📄 tgz.am(992 B)
📄 toolchain-simd.m4(9.44 KB)
📄 user-clock_gettime.m4(387 B)
📄 user-dracut.m4(545 B)
📄 user-gettext.m4(171 B)
📄 user-libaio.m4(218 B)
📄 user-libblkid.m4(327 B)
📄 user-libcrypto.m4(325 B)
📄 user-libexec.m4(246 B)
📄 user-libtirpc.m4(990 B)
📄 user-libudev.m4(457 B)
📄 user-libuuid.m4(250 B)
📄 user-makedev.m4(793 B)
📄 user-pam.m4(1 KB)
📄 user-runstatedir.m4(208 B)
📄 user-systemd.m4(1.88 KB)
📄 user-sysvinit.m4(276 B)
📄 user-udev.m4(724 B)
📄 user-zlib.m4(230 B)
📄 user.m4(1.14 KB)
📄 zfs-build.m4(16.37 KB)
📄 zfs-meta.m4(6.68 KB)

Editing: kernel-xattr-handler.m4

dnl #
dnl # 2.6.35 API change,
dnl # The 'struct xattr_handler' was constified in the generic
dnl # super_block structure.
dnl #
AC_DEFUN([ZFS_AC_KERNEL_SRC_CONST_XATTR_HANDLER], [
	ZFS_LINUX_TEST_SRC([const_xattr_handler], [
		#include <linux/fs.h>
		#include <linux/xattr.h>

const struct xattr_handler xattr_test_handler = {
			.prefix	= "test",
			.get	= NULL,
			.set	= NULL,
		};

const struct xattr_handler *xattr_handlers[] = {
			&xattr_test_handler,
		};

const struct super_block sb __attribute__ ((unused)) = {
			.s_xattr = xattr_handlers,
		};
	],[])
])

AC_DEFUN([ZFS_AC_KERNEL_CONST_XATTR_HANDLER], [
	AC_MSG_CHECKING([whether super_block uses const struct xattr_handler])
	ZFS_LINUX_TEST_RESULT([const_xattr_handler], [
		AC_MSG_RESULT([yes])
	],[
		ZFS_LINUX_TEST_ERROR([const xattr_handler])
	])
])

dnl #
dnl # 4.5 API change,
dnl # struct xattr_handler added new member "name".
dnl # xattr_handler which matches to whole name rather than prefix should use
dnl # "name" instead of "prefix", e.g. "system.posix_acl_access"
dnl #
AC_DEFUN([ZFS_AC_KERNEL_SRC_XATTR_HANDLER_NAME], [
	ZFS_LINUX_TEST_SRC([xattr_handler_name], [
		#include <linux/xattr.h>

static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.name = XATTR_NAME_POSIX_ACL_ACCESS,
		};
	],[])
])

AC_DEFUN([ZFS_AC_KERNEL_XATTR_HANDLER_NAME], [
	AC_MSG_CHECKING([whether xattr_handler has name])
	ZFS_LINUX_TEST_RESULT([xattr_handler_name], [
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_XATTR_HANDLER_NAME, 1,
		    [xattr_handler has name])
	],[
		AC_MSG_RESULT(no)
	])
])

dnl #
dnl # Supported xattr handler get() interfaces checked newest to oldest.
dnl #
AC_DEFUN([ZFS_AC_KERNEL_SRC_XATTR_HANDLER_GET], [
	ZFS_LINUX_TEST_SRC([xattr_handler_get_dentry_inode], [
		#include <linux/xattr.h>

int get(const struct xattr_handler *handler,
		    struct dentry *dentry, struct inode *inode,
		    const char *name, void *buffer, size_t size) { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.get = get,
		};
	],[])

ZFS_LINUX_TEST_SRC([xattr_handler_get_xattr_handler], [
		#include <linux/xattr.h>

int get(const struct xattr_handler *handler,
		    struct dentry *dentry, const char *name,
		    void *buffer, size_t size) { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.get = get,
		};
	],[])

ZFS_LINUX_TEST_SRC([xattr_handler_get_dentry], [
		#include <linux/xattr.h>

int get(struct dentry *dentry, const char *name,
		    void *buffer, size_t size, int handler_flags)
		    { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.get = get,
		};
	],[])
])

AC_DEFUN([ZFS_AC_KERNEL_XATTR_HANDLER_GET], [
	dnl #
	dnl # 4.7 API change,
	dnl # The xattr_handler->get() callback was changed to take both
	dnl # dentry and inode.
	dnl #
	AC_MSG_CHECKING([whether xattr_handler->get() wants dentry and inode])
	ZFS_LINUX_TEST_RESULT([xattr_handler_get_dentry_inode], [
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_XATTR_GET_DENTRY_INODE, 1,
		    [xattr_handler->get() wants both dentry and inode])
	],[
		dnl #
		dnl # 4.4 API change,
		dnl # The xattr_handler->get() callback was changed to take a
		dnl # attr_handler, and handler_flags argument was removed and
		dnl # should be accessed by handler->flags.
		dnl #
		AC_MSG_RESULT(no)
		AC_MSG_CHECKING(
		    [whether xattr_handler->get() wants xattr_handler])
		ZFS_LINUX_TEST_RESULT([xattr_handler_get_xattr_handler], [
			AC_MSG_RESULT(yes)
			AC_DEFINE(HAVE_XATTR_GET_HANDLER, 1,
			    [xattr_handler->get() wants xattr_handler])
		],[
			dnl #
			dnl # 2.6.33 API change,
			dnl # The xattr_handler->get() callback was changed
			dnl # to take a dentry instead of an inode, and a
			dnl # handler_flags argument was added.
			dnl #
			AC_MSG_RESULT(no)
			AC_MSG_CHECKING(
			    [whether xattr_handler->get() wants dentry])
			ZFS_LINUX_TEST_RESULT([xattr_handler_get_dentry], [
				AC_MSG_RESULT(yes)
				AC_DEFINE(HAVE_XATTR_GET_DENTRY, 1,
				    [xattr_handler->get() wants dentry])
			],[
				ZFS_LINUX_TEST_ERROR([xattr get()])
			])
		])
	])
])

dnl #
dnl # Supported xattr handler set() interfaces checked newest to oldest.
dnl #
AC_DEFUN([ZFS_AC_KERNEL_SRC_XATTR_HANDLER_SET], [
	ZFS_LINUX_TEST_SRC([xattr_handler_set_dentry_inode], [
		#include <linux/xattr.h>

int set(const struct xattr_handler *handler,
		    struct dentry *dentry, struct inode *inode,
		    const char *name, const void *buffer,
		    size_t size, int flags)
		    { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.set = set,
		};
	],[])

ZFS_LINUX_TEST_SRC([xattr_handler_set_xattr_handler], [
		#include <linux/xattr.h>

int set(const struct xattr_handler *handler,
		    struct dentry *dentry, const char *name,
		    const void *buffer, size_t size, int flags)
		    { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.set = set,
		};
	],[])

ZFS_LINUX_TEST_SRC([xattr_handler_set_dentry], [
		#include <linux/xattr.h>

int set(struct dentry *dentry, const char *name,
		    const void *buffer, size_t size, int flags,
		    int handler_flags) { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.set = set,
		};
	],[])
])

AC_DEFUN([ZFS_AC_KERNEL_XATTR_HANDLER_SET], [
	dnl #
	dnl # 4.7 API change,
	dnl # The xattr_handler->set() callback was changed to take both
	dnl # dentry and inode.
	dnl #
	AC_MSG_CHECKING([whether xattr_handler->set() wants dentry and inode])
	ZFS_LINUX_TEST_RESULT([xattr_handler_set_dentry_inode], [
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_XATTR_SET_DENTRY_INODE, 1,
		    [xattr_handler->set() wants both dentry and inode])
	],[
		dnl #
		dnl # 4.4 API change,
		dnl # The xattr_handler->set() callback was changed to take a
		dnl # xattr_handler, and handler_flags argument was removed and
		dnl # should be accessed by handler->flags.
		dnl #
		AC_MSG_RESULT(no)
		AC_MSG_CHECKING(
		    [whether xattr_handler->set() wants xattr_handler])
		ZFS_LINUX_TEST_RESULT([xattr_handler_set_xattr_handler], [
			AC_MSG_RESULT(yes)
			AC_DEFINE(HAVE_XATTR_SET_HANDLER, 1,
			    [xattr_handler->set() wants xattr_handler])
		],[
			dnl #
			dnl # 2.6.33 API change,
			dnl # The xattr_handler->set() callback was changed
			dnl # to take a dentry instead of an inode, and a
			dnl # handler_flags argument was added.
			dnl #
			AC_MSG_RESULT(no)
			AC_MSG_CHECKING(
			    [whether xattr_handler->set() wants dentry])
			ZFS_LINUX_TEST_RESULT([xattr_handler_set_dentry], [
				AC_MSG_RESULT(yes)
				AC_DEFINE(HAVE_XATTR_SET_DENTRY, 1,
				    [xattr_handler->set() wants dentry])
			],[
				ZFS_LINUX_TEST_ERROR([xattr set()])
			])
		])
	])
])

dnl #
dnl # Supported xattr handler list() interfaces checked newest to oldest.
dnl #
AC_DEFUN([ZFS_AC_KERNEL_SRC_XATTR_HANDLER_LIST], [
	ZFS_LINUX_TEST_SRC([xattr_handler_list_simple], [
		#include <linux/xattr.h>

bool list(struct dentry *dentry) { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.list = list,
		};
	],[])

ZFS_LINUX_TEST_SRC([xattr_handler_list_xattr_handler], [
		#include <linux/xattr.h>

size_t list(const struct xattr_handler *handler,
		    struct dentry *dentry, char *list, size_t list_size,
		    const char *name, size_t name_len) { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.list = list,
		};
	],[])

ZFS_LINUX_TEST_SRC([xattr_handler_list_dentry], [
		#include <linux/xattr.h>

size_t list(struct dentry *dentry,
		    char *list, size_t list_size,
		    const char *name, size_t name_len,
		    int handler_flags) { return 0; }
		static const struct xattr_handler
		    xops __attribute__ ((unused)) = {
			.list = list,
		};
	],[])
])

AC_DEFUN([ZFS_AC_KERNEL_XATTR_HANDLER_LIST], [
	dnl # 4.5 API change,
	dnl # The xattr_handler->list() callback was changed to take only a
	dnl # dentry and it only needs to return if it's accessible.
	AC_MSG_CHECKING([whether xattr_handler->list() wants simple])
	ZFS_LINUX_TEST_RESULT([xattr_handler_list_simple], [
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_XATTR_LIST_SIMPLE, 1,
		    [xattr_handler->list() wants simple])
	],[
		dnl #
		dnl # 4.4 API change,
		dnl # The xattr_handler->list() callback was changed to take a
		dnl # xattr_handler, and handler_flags argument was removed
		dnl # and should be accessed by handler->flags.
		dnl #
		AC_MSG_RESULT(no)
		AC_MSG_CHECKING(
		    [whether xattr_handler->list() wants xattr_handler])
		ZFS_LINUX_TEST_RESULT([xattr_handler_list_xattr_handler], [
			AC_MSG_RESULT(yes)
			AC_DEFINE(HAVE_XATTR_LIST_HANDLER, 1,
			    [xattr_handler->list() wants xattr_handler])
		],[
			dnl #
			dnl # 2.6.33 API change,
			dnl # The xattr_handler->list() callback was changed
			dnl # to take a dentry instead of an inode, and a
			dnl # handler_flags argument was added.
			dnl #
			AC_MSG_RESULT(no)
			AC_MSG_CHECKING(
			    [whether xattr_handler->list() wants dentry])
			ZFS_LINUX_TEST_RESULT([xattr_handler_list_dentry], [
				AC_MSG_RESULT(yes)
				AC_DEFINE(HAVE_XATTR_LIST_DENTRY, 1,
				    [xattr_handler->list() wants dentry])
			],[
				ZFS_LINUX_TEST_ERROR([xattr list()])
			])
		])
	])
])

dnl #
dnl # 3.7 API change,
dnl # The posix_acl_{from,to}_xattr functions gained a new
dnl # parameter: user_ns
dnl #
AC_DEFUN([ZFS_AC_KERNEL_SRC_POSIX_ACL_FROM_XATTR_USERNS], [
	ZFS_LINUX_TEST_SRC([posix_acl_from_xattr_userns], [
		#include <linux/cred.h>
		#include <linux/fs.h>
		#include <linux/posix_acl_xattr.h>
	],[
		posix_acl_from_xattr(&init_user_ns, NULL, 0);
	])
])

AC_DEFUN([ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS], [
	AC_MSG_CHECKING([whether posix_acl_from_xattr() needs user_ns])
	ZFS_LINUX_TEST_RESULT([posix_acl_from_xattr_userns], [
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_POSIX_ACL_FROM_XATTR_USERNS, 1,
		    [posix_acl_from_xattr() needs user_ns])
	],[
		ZFS_LINUX_TEST_ERROR([posix_acl_from_xattr()])
	])
])

dnl #
dnl # 4.9 API change,
dnl # iops->{set,get,remove}xattr and generic_{set,get,remove}xattr are
dnl # removed. xattr operations will directly go through sb->s_xattr.
dnl #
AC_DEFUN([ZFS_AC_KERNEL_SRC_GENERIC_SETXATTR], [
	ZFS_LINUX_TEST_SRC([have_generic_setxattr], [
		#include <linux/fs.h>
		#include <linux/xattr.h>

static const struct inode_operations
		    iops __attribute__ ((unused)) = {
			.setxattr = generic_setxattr
		};
	],[])
])

AC_DEFUN([ZFS_AC_KERNEL_GENERIC_SETXATTR], [
	AC_MSG_CHECKING([whether generic_setxattr() exists])
	ZFS_LINUX_TEST_RESULT([have_generic_setxattr], [
		AC_MSG_RESULT(yes)
		AC_DEFINE(HAVE_GENERIC_SETXATTR, 1,
		    [generic_setxattr() exists])
	],[
		AC_MSG_RESULT(no)
	])
])

AC_DEFUN([ZFS_AC_KERNEL_SRC_XATTR], [
	ZFS_AC_KERNEL_SRC_CONST_XATTR_HANDLER
	ZFS_AC_KERNEL_SRC_XATTR_HANDLER_NAME
	ZFS_AC_KERNEL_SRC_XATTR_HANDLER_GET
	ZFS_AC_KERNEL_SRC_XATTR_HANDLER_SET
	ZFS_AC_KERNEL_SRC_XATTR_HANDLER_LIST
	ZFS_AC_KERNEL_SRC_POSIX_ACL_FROM_XATTR_USERNS
	ZFS_AC_KERNEL_SRC_GENERIC_SETXATTR
])

AC_DEFUN([ZFS_AC_KERNEL_XATTR], [
	ZFS_AC_KERNEL_CONST_XATTR_HANDLER
	ZFS_AC_KERNEL_XATTR_HANDLER_NAME
	ZFS_AC_KERNEL_XATTR_HANDLER_GET
	ZFS_AC_KERNEL_XATTR_HANDLER_SET
	ZFS_AC_KERNEL_XATTR_HANDLER_LIST
	ZFS_AC_KERNEL_POSIX_ACL_FROM_XATTR_USERNS
	ZFS_AC_KERNEL_GENERIC_SETXATTR
])

003 File Manager

Editing: kernel-xattr-handler.m4

Upload File

Create Folder