File Manager

003 File Manager

Current Path: /usr/src/sys/amd64/linux32

📁 ..
📄 Makefile(105 B)
📄 linux.h(14.87 KB)
📄 linux32_dummy_machdep.c(2.69 KB)
📄 linux32_genassym.c(651 B)
📄 linux32_locore.asm(3.77 KB)
📄 linux32_machdep.c(18.74 KB)
📄 linux32_proto.h(118.31 KB)
📄 linux32_support.s(4.81 KB)
📄 linux32_syscall.h(14.88 KB)
📄 linux32_syscalls.c(19.87 KB)
📄 linux32_sysent.c(71.57 KB)
📄 linux32_systrace_args.c(161.67 KB)
📄 linux32_sysvec.c(31.03 KB)
📄 linux32_vdso.lds.s(1.29 KB)
📄 syscalls.conf(296 B)
📄 syscalls.master(40.42 KB)

Editing: linux32_vdso.lds.s

/*
 * Linker script for 32-bit vDSO.
 * Copied from Linux kernel arch/x86/vdso/vdso-layout.lds.S
 * and arch/x86/vdso/vdso32/vdso32.lds.S
 *
 * $FreeBSD$
 */

SECTIONS
{
	. = . + SIZEOF_HEADERS;

.hash		: { *(.hash) }			:text
	.gnu.hash	: { *(.gnu.hash) }
	.dynsym		: { *(.dynsym) }
	.dynstr		: { *(.dynstr) }
	.gnu.version	: { *(.gnu.version) }
	.gnu.version_d	: { *(.gnu.version_d) }
	.gnu.version_r	: { *(.gnu.version_r) }

.note		: { *(.note.*) }		:text	:note

.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
	.eh_frame	: { KEEP (*(.eh_frame)) }	:text

.dynamic	: { *(.dynamic) }		:text	:dynamic

.rodata		: { *(.rodata*) }		:text
	.data		: {
	      *(.data*)
	      *(.sdata*)
	      *(.got.plt) *(.got)
	      *(.gnu.linkonce.d.*)
	      *(.bss*)
	      *(.dynbss*)
	      *(.gnu.linkonce.b.*)
	}

.altinstructions	: { *(.altinstructions) }
	.altinstr_replacement	: { *(.altinstr_replacement) }

. = ALIGN(0x100);
	.text		: { *(.text*) }			:text	=0x90909090
}

PHDRS
{
	text		PT_LOAD		FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
	dynamic		PT_DYNAMIC	FLAGS(4);		/* PF_R */
	note		PT_NOTE		FLAGS(4);		/* PF_R */
	eh_frame_hdr	PT_GNU_EH_FRAME;
}

ENTRY(linux32_vsyscall);

VERSION
{
	LINUX_2.5 {
	global:
		linux32_vsyscall;
		linux32_sigcode;
		linux32_rt_sigcode;
		linux_platform;
	local: *;
	};
}

003 File Manager

Editing: linux32_vdso.lds.s

Upload File

Create Folder