File Manager

003 File Manager

Current Path: /usr/src/sys/amd64/linux

📁 ..
📄 Makefile(103 B)
📄 linux.h(10.02 KB)
📄 linux_dummy_machdep.c(2.35 KB)
📄 linux_genassym.c(497 B)
📄 linux_locore.asm(2.32 KB)
📄 linux_machdep.c(8.71 KB)
📄 linux_proto.h(98.12 KB)
📄 linux_ptrace.c(16.95 KB)
📄 linux_support.s(4.81 KB)
📄 linux_syscall.h(11.73 KB)
📄 linux_syscalls.c(18.3 KB)
📄 linux_sysent.c(69.13 KB)
📄 linux_systrace_args.c(139.2 KB)
📄 linux_sysvec.c(26.1 KB)
📄 linux_vdso.lds.s(1.31 KB)
📄 syscalls.conf(278 B)
📄 syscalls.master(34.24 KB)

Editing: linux_vdso.lds.s

/*
 * Linker script for 64-bit vDSO.
 * Copied from Linux kernel arch/x86/vdso/vdso-layout.lds.S
 *
 * $FreeBSD$
 */

SECTIONS
{
	. = . + SIZEOF_HEADERS;

.hash		: { *(.hash) }			:text
	.gnu.hash	: { *(.gnu.hash) }
	.dynsym		: { *(.dynsym) }
	.dynstr		: { *(.dynstr) }
	.gnu.version	: { *(.gnu.version) }
	.gnu.version_d	: { *(.gnu.version_d) }
	.gnu.version_r	: { *(.gnu.version_r) }

.note		: { *(.note.*) }		:text	:note

.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
	.eh_frame	: { KEEP (*(.eh_frame)) }	:text

.dynamic	: { *(.dynamic) }		:text	:dynamic

.rodata		: { *(.rodata*) }		:text
	.data		: {
	      *(.data*)
	      *(.sdata*)
	      *(.got.plt) *(.got)
	      *(.gnu.linkonce.d.*)
	      *(.bss*)
	      *(.dynbss*)
	      *(.gnu.linkonce.b.*)
	}

.altinstructions	: { *(.altinstructions) }
	.altinstr_replacement	: { *(.altinstr_replacement) }

. = ALIGN(0x100);
	.text		: { *(.test .text*) }			:text	=0x90909090
}

PHDRS
{
	text		PT_LOAD		FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
	dynamic		PT_DYNAMIC	FLAGS(4);		/* PF_R */
	note		PT_NOTE		FLAGS(4);		/* PF_R */
	eh_frame_hdr	PT_GNU_EH_FRAME;
}

VERSION
{
	LINUX_2.6 {
	global:
		time;
		__vdso_time;
		gettimeofday;
		__vdso_gettimeofday;
		getcpu;
		__vdso_getcpu;
		clock_gettime;
		__vdso_clock_gettime;
		linux_rt_sigcode;
		linux_platform;
	local: *;
	};
}

003 File Manager

Editing: linux_vdso.lds.s

Upload File

Create Folder