File Manager

003 File Manager

Current Path: /usr/src/sys/i386/linux

📁 ..
📄 Makefile(103 B)
📄 imgact_linux.c(6.55 KB)
📄 linux.h(13.51 KB)
📄 linux_copyout.c(4.1 KB)
📄 linux_dummy_machdep.c(2.79 KB)
📄 linux_genassym.c(746 B)
📄 linux_locore.asm(3.74 KB)
📄 linux_machdep.c(17.55 KB)
📄 linux_proto.h(116.57 KB)
📄 linux_ptrace.c(11.58 KB)
📄 linux_syscall.h(14.35 KB)
📄 linux_syscalls.c(19.9 KB)
📄 linux_sysent.c(71.68 KB)
📄 linux_systrace_args.c(163.01 KB)
📄 linux_sysvec.c(30.26 KB)
📄 linux_vdso.lds.s(1.26 KB)
📄 syscalls.conf(278 B)
📄 syscalls.master(40.41 KB)

Editing: linux_vdso.lds.s

/*
 * Linker script for 32-bit vDSO.
 * Copied from Linux kernel arch/x86/vdso/vdso-layout.lds.S
 * and arch/x86/vdso/vdso32/vdso32.lds.S
 *
 * $FreeBSD$
 */

SECTIONS
{
	. = . + SIZEOF_HEADERS;

.hash		: { *(.hash) }			:text
	.gnu.hash	: { *(.gnu.hash) }
	.dynsym		: { *(.dynsym) }
	.dynstr		: { *(.dynstr) }
	.gnu.version	: { *(.gnu.version) }
	.gnu.version_d	: { *(.gnu.version_d) }
	.gnu.version_r	: { *(.gnu.version_r) }

.note		: { *(.note.*) }		:text	:note

.eh_frame_hdr	: { *(.eh_frame_hdr) }		:text	:eh_frame_hdr
	.eh_frame	: { KEEP (*(.eh_frame)) }	:text

.dynamic	: { *(.dynamic) }		:text	:dynamic

.rodata		: { *(.rodata*) }		:text
	.data		: {
	      *(.data*)
	      *(.sdata*)
	      *(.got.plt) *(.got)
	      *(.gnu.linkonce.d.*)
	      *(.bss*)
	      *(.dynbss*)
	      *(.gnu.linkonce.b.*)
	}

.altinstructions	: { *(.altinstructions) }
	.altinstr_replacement	: { *(.altinstr_replacement) }

. = ALIGN(0x100);
	.text		: { *(.text*) }			:text	=0x90909090
}

PHDRS
{
	text		PT_LOAD		FLAGS(5) FILEHDR PHDRS; /* PF_R|PF_X */
	dynamic		PT_DYNAMIC	FLAGS(4);		/* PF_R */
	note		PT_NOTE		FLAGS(4);		/* PF_R */
	eh_frame_hdr	PT_GNU_EH_FRAME;
}

ENTRY(linux_vsyscall);

VERSION
{
	LINUX_2.5 {
	global:
		linux_vsyscall;
		linux_sigcode;
		linux_rt_sigcode;
	local: *;
	};
}

003 File Manager

Editing: linux_vdso.lds.s

Upload File

Create Folder