File Manager

003 File Manager

Current Path: /usr/src/contrib/ntp/sntp/m4

📁 ..
📄 ax_c99_struct_init.m4(1.64 KB)
📄 define_dir.m4(1.16 KB)
📄 hms_search_lib.m4(701 B)
📄 libtool.m4(298.56 KB)
📄 ltoptions.m4(14.17 KB)
📄 ltsugar.m4(4.28 KB)
📄 ltversion.m4(699 B)
📄 lt~obsolete.m4(6 KB)
📄 ntp_af_unspec.m4(597 B)
📄 ntp_cacheversion.m4(4.08 KB)
📄 ntp_compiler.m4(5.15 KB)
📄 ntp_crosscompile.m4(300 B)
📄 ntp_crypto_rand.m4(1.41 KB)
📄 ntp_debug.m4(549 B)
📄 ntp_dir_sep.m4(589 B)
📄 ntp_facilitynames.m4(797 B)
📄 ntp_googletest.m4(1.35 KB)
📄 ntp_harden.m4(1.19 KB)
📄 ntp_ipv6.m4(10.55 KB)
📄 ntp_lib_m.m4(388 B)
📄 ntp_libevent.m4(6.34 KB)
📄 ntp_libntp.m4(24.98 KB)
📄 ntp_lineeditlibs.m4(2.9 KB)
📄 ntp_locinfo.m4(3.2 KB)
📄 ntp_openssl.m4(9.84 KB)
📄 ntp_pkg_config.m4(673 B)
📄 ntp_problemtests.m4(1.96 KB)
📄 ntp_prog_cc.m4(460 B)
📄 ntp_rlimit.m4(2.55 KB)
📄 ntp_sntp.m4(643 B)
📄 ntp_sysexits.m4(352 B)
📄 ntp_unitytest.m4(531 B)
📄 ntp_ver_suffix.m4(404 B)
📄 ntp_vpathhack.m4(1.52 KB)
📄 openldap-thread-check.m4(18.72 KB)
📄 openldap.m4(32.08 KB)
📄 os_cflags.m4(3.27 KB)
📄 snprintf.m4(11.16 KB)
📄 sntp_problemtests.m4(1.35 KB)
📄 version.m4(39 B)

Editing: ntp_cacheversion.m4

# NTP_CACHEVERSION(component, version)
# ------------------------------------
# compare this configure script's cache version stamp with the stamp
# saved by the prior run in config.cache.  If they differ, clear all
# cache variables to avoid using results cached with a script that
# is known to differ in a cache-invalidating manner.
#
# Note: use immediately following AC_INIT in configure.ac, as clearing
# all _cv_ variables only makes sense immediately after loading, before
# use or modification.
#
# The top-level configure.ac in a subtree using NTP_CACHEVERSION
# will clear a previous cache lacking any saved cache version number,
# while children do not.  This comes into play only when introducing
# NTP_CACHEVERSION where it had not been previously used:  Previous
# cached results are presumed incompatible and not used.  The reason
# children do not flush the cached is it is shared with the parent and
# the children can rely on the parent having cleared any cache variables
# predating this mechanism.  Therefore the child can rely on the 
# config.cache generated by the parent on the first run despite not 
# finding the child version stamp in it.
#
# See html/copyright.html or COPYRIGHT in plain text.

AC_DEFUN_ONCE([NTP_CACHEVERSION], [
    AC_BEFORE([$0], [AM_INIT_AUTOMAKE])dnl
    AC_BEFORE([$0], [AC_CONFIG_HEADERS])dnl
    AC_BEFORE([$0], [AC_PROG_CC])dnl
    AC_BEFORE([$0], [AC_CONFIG_SUBDIRS])dnl

ntp_cache_flush=1
    
    case "$ntp_cv_[$1]_cache_version" in
     [$2])
	# same version, good
	ntp_cache_flush=0
	;;
     '')
	# No cache, predates ntp_cv_$1_cache_version, or is empty.
	case "$cache_file" in
	 /dev/null)
	    ntp_cache_flush=0
	    ;;
	 *)
	    case "$NTP_CACHEVERSION_PARENT" in
	     '')
		# Do not clear the cache immediately after it is created
		# empty as it is noisy.  Differentiate a newly-created 
		# config.cache from one predating the cache version 
		# mechanism by looking for the first cached variable set 
		# by Autoconf
		case "$ac_cv_path_install" in
		 '')
		    # empty config.cache file
		    ntp_cache_flush=0
		esac
		;;
	     *)
		# Parent configure just created cache from empty,
		# flushing would be counterproductive.
		ntp_cache_flush=0;
		;;
	    esac
	esac
	;;
     *)
	# configure cache version mismatches config.cache version
	;;
    esac
    
    case "$ntp_cache_flush" in
     1)
	c_version="${ntp_cv_[$1]_cache_version:-(no version found)}"
	
	# Do we flush all variables or exclude others' version stamps?

case "$NTP_CACHEVERSION_PARENT" in
	 '')
	    # Clear all *_cv_* variables including our child subdirs'
	    # ntp_cv_*_cache_version variables.  This prevents subdir
	    # configure scripts from noticing a version mismatch just
	    # after the top configure in the invocation cleared and
	    # recreated the cache.
	
	    c_varname_list=`set |
			    sed -n -e 's/=.*$//' \
				   -e '/_cv_/p'
			   `
	    ;;
	 *)
	    # This is not the top configure this particular invocation.
	    # Clear all *_cv_* variables sparing the version stamps
	    # of other configure scripts, so we don't trigger
	    # useless repeated clearings.

c_varname_list=`set |
			    sed -n -e 's/=.*$//' \
				   -e '/ntp_cv_.*_cache_version/d' \
				   -e '/_cv_/p'
			   `
	esac
	
	for c_varname in $c_varname_list
	do
	    dnl AS_UNSET([$c_varname])
	    dnl With Autoconf 2.61 and automake 1.10.3, using AS_UNSET
	    dnl here triggers generation of a syntax error in configure.
	    dnl Once we require a newer Autoconf we can revert to the
	    dnl AS_UNSET code.
	    { eval $c_varname=; unset $c_varname; }
	done
	
	AC_MSG_NOTICE([[$cache_file saved by another version, ignored.]])
	AC_MSG_NOTICE([[configure script cache version: ]][$2])
	AC_MSG_NOTICE([[$cache_file version: $c_version]])
	AS_UNSET([c_varname])
	AS_UNSET([c_varname_list])
	AS_UNSET([c_version])
    esac

AS_UNSET([ntp_cache_flush])

# save configure version in config.cache for next time
    ntp_cv_[$1]_cache_version="[$2]"

# let any subdir configure.ac NTP_CACHEVERSION invocations
    # know they are not the top level.
    NTP_CACHEVERSION_PARENT='[$1]' ; export NTP_CACHEVERSION_PARENT
])dnl

003 File Manager

Editing: ntp_cacheversion.m4

Upload File

Create Folder